@ECHO OFF
REM -------------------------------------------------------------------------------
REM File    : ifortfixme.bat
REM
REM Abstract: 
REM        Please run this .bat file from a Microsoft Visual Studio 2005* 
REM        command prompt or the build environment of Intel(R) Visual Fortran Compiler. 
REM        This batch file copies the files under "1033" folders 
REM        created by the Intel Visual Fortran Compiler IDE integration installation 
REM        to a folder with the corresponding locale name 
REM        used by the Microsoft Visual Studio 2005*, i.e. 
REM               1031 for German 
REM               1041 for Japanese
REM
REM "Usage:    ifortfixme {encoding}"
REM
REM  *  Other names and brands may be claimed as the property of others.


if "%VSINSTALLDIR%"== "" goto Usage
if "%~1" == ""  goto Usage

:checkdirexist
IF NOT EXIST "%VSINSTALLDIR%\." goto Usage

:ifortideinstalled
IF NOT EXIST "%VSINSTALLDIR%\Intel Fortran\." goto UsageNoIfort

:checkecoding 
if "%~1" == "1033"  goto :completed

echo starting copying necessary files for %~1 locale > ifortlog.txt 2>&1
echo creating directories with %~1 name
echo creating directories with %~1 name >> ifortlog.txt 2>&1
mkdir "%VSINSTALLDIR%\Common7\IDE\ProjectTemplates\IntelFortran\COM Server\%~1" >>ifortlog.txt 2>&1
mkdir "%VSINSTALLDIR%\Common7\IDE\ProjectTemplates\IntelFortran\Console Application\%~1" >>ifortlog.txt 2>&1
mkdir "%VSINSTALLDIR%\Common7\IDE\ProjectTemplates\IntelFortran\Library\%~1" >>ifortlog.txt 2>&1
mkdir "%VSINSTALLDIR%\Common7\IDE\ProjectTemplates\IntelFortran\QuickWin Application\%~1" >>ifortlog.txt 2>&1
mkdir "%VSINSTALLDIR%\Common7\IDE\ProjectTemplates\IntelFortran\Windowing Application\%~1" >>ifortlog.txt 2>&1

echo copying files
echo copying files >> ifortlog.txt 2>&1
copy /Y "%VSINSTALLDIR%\Common7\IDE\ProjectTemplates\IntelFortran\COM Server\1033\*.*" "%VSINSTALLDIR%\Common7\IDE\ProjectTemplates\IntelFortran\COM Server\%~1" >>ifortlog.txt 2>&1
copy /Y "%VSINSTALLDIR%\Common7\IDE\ProjectTemplates\IntelFortran\Console Application\1033\*.*" "%VSINSTALLDIR%\Common7\IDE\ProjectTemplates\IntelFortran\Console Application\%~1" >>ifortlog.txt 2>&1
copy /Y "%VSINSTALLDIR%\Common7\IDE\ProjectTemplates\IntelFortran\Library\1033\*.*" "%VSINSTALLDIR%\Common7\IDE\ProjectTemplates\IntelFortran\Library\%~1" >>ifortlog.txt 2>&1
copy /Y "%VSINSTALLDIR%\Common7\IDE\ProjectTemplates\IntelFortran\QuickWin Application\1033\*.*" "%VSINSTALLDIR%\Common7\IDE\ProjectTemplates\IntelFortran\QuickWin Application\%~1" >>ifortlog.txt 2>&1
copy /Y "%VSINSTALLDIR%\Common7\IDE\ProjectTemplates\IntelFortran\Windowing Application\1033\*.*" "%VSINSTALLDIR%\Common7\IDE\ProjectTemplates\IntelFortran\Windowing Application\%~1" >>ifortlog.txt 2>&1

echo please wait a minute or two while devenv is reset!
echo running "%VSINSTALLDIR%\Common7\IDE\devenv" /setup >> ifortlog.txt 2>&1
"%VSINSTALLDIR%\Common7\IDE\devenv" /setup
goto :completed

:Usage
echo Bad parameters or no required environment variable
echo Usage: ifortfixme {encoding}
echo        1. encoding: 
echo              1031 for German 
echo              1041 for Japanese
echo	    2. Environment variable VSINSTALLDIR should be defined to point
echo	       to the root of Visual Studio 2005
echo        3. A log file "ifortlog.txt" will be created at the current directory. 
goto end

:UsageNoIfort
echo ******************************************
echo Did NOT detect the Intel Fortran IDE integration. 
echo Please make sure VSINSTALLDIR environment variable points 
echo        to the Visual Studio 2005 root directory.
echo  
echo Usage: ifortfixme {encoding}
echo ******************************************
goto end

:completed
echo Completed! >> ifortlog.txt 2>&1

:end